Aminet 37/Aminet 37 (2000)(Schatztruhe)[!][Jun 2000].iso/Aminet/dev/basic/PureBasicU1.40.lha/PureBasic_UpdateV1.40/PureBasic/Install

Text File | 2000-03-19 | 3KB | 171 lines

;*
;* Install script for PureBasic V1.40
;*
;* Done by 'AlphaSND'
;*


;*** Autodetection for langage !

(if (> (exists ("env:Language")) 0)
  (set Langage_AmigaOS (getenv "Language"))
)

(set #Langage 0)

(if (= "english"  Langage_AmigaOS) (set #Langage 0))
(if (= "français" Langage_AmigaOS) (set #Langage 1))
(if (= "deutsch"  Langage_AmigaOS) (set #Langage 2))

(if (= #Langage 0)
  (
    (set #WelcomePrompt "\nWelcome !\nThank you to let give a try to PureBasic.\n\nPlease choose the langage for PureBasic:")
  )
)


;*** Francais ***

(if (= #Langage 1)
  (
    (set #WelcomePrompt "\nBienvenue !\nMerci de prendre la peine d'installer PureBasic.\n\nChoisissez la langue qui sera utilisée par PureBasic:")
  )
)


;*** Deutsch ***


(if (= #Langage 2)
  (
    (set #WelcomePrompt "\nWillkommen !\nVielen Dank, dass Sie PureBasic ausprobieren.\n\nBitte wählen Sie Ihre Sprache für PureBasic:")
  )
)


(complete 0)

(set #Langage
  (askchoice
    (prompt #WelcomePrompt)
    (Help "")
    (choices
      "English"
      "Francais"
      "Deutsch"
    )
    (default #Langage)
  )
)


;*** English ***

(if (= #Langage 0)
  (
    (set #FBDirPrompt "Where do you want to install PureBasic ?\nA Drawer called 'PureBasic' will be created.")
    (set #FBDirHelp "")
    (set #FBLangSel "Select the languages to install with PureBasic.")
    (set #FBIcon "Select your icons type")
  )
)


;*** Francais ***

(if (= #Langage 1)
  (
    (set #FBDirPrompt "Où voulez-vous installer PureBasic ?\nUn tiroir nommé 'PureBasic' sera automatiquement créé.")
    (set #FBDirHelp "")
    (set #FBLangSel "Choisissez quel langage vous voulez avoir pour PureBasic")
    (set #FBIcon "Choisissez votre type d'icone")
  )
)


;*** Deutsch ***

(if (= #Langage 2)
  (
    (set #FBDirPrompt "Wo möchten Sie PureBasic installieren?\nEin Verzeichnis genannt 'PureBasic' wird erstellt.")
    (set #FBDirHelp "")
    (set #FBLangSel "Wählen Sie die Sprachen, die mit PureBasic installiert werden sollen.")
    (set #FBIcon "Wählen Sie den gewünschten Icon-Typ.")
  )
)

;*** Directory Select ***

(complete 5)

(set DestDir
  (askdir
    (prompt #FBDirPrompt)
    (help #FBDirHelp)
    (default "PureBasic:/")
  )
)

(set DestDir (expandpath DestDir))
(set @default-dest (tackon DestDir "PureBasic"))

(set Base_Dir @default-dest)

(makedir @default-dest (infos))

(set FBench_dir @default-dest)

(set Help_Dir (cat Base_Dir "/Help/"))

;*** Main Files ***

(complete 20)

(copyfiles
  (source "PureBasic/")
  (dest @default-dest)
  (pattern "#?")
  (optional "nofail")
  (infos)
)

(complete 70)

(copyfiles
  (source "")
  (dest DestDir)
  (pattern "PureBasic.info")
)


;*** Locale Help Files ***

(complete 80)

(if (= #Langage 1)
  (
    (copyfiles
      (source "Francais/")
      (dest Base_Dir)
      (pattern "#?")
      (optional "nofail")
    )
  )
)


(if (= #Langage 2)
  (
    (copyfiles
      (source "Deutsch/")
      (dest Base_Dir)
      (pattern "#?")
      (optional "nofail")
    )
  )
)

(complete 100)